[原]VisualC++信息安全编程（1）内联汇编实现NT下读MBR

winston

MBR，全称为Master Boot Record，即硬盘的主引导记录。　　为了便于理解，一般将MBR分为广义和狭义两种：广义的MBR包含整个扇区（引导程序、分区表及分隔标识），也就是上面所说的主引导记录；而狭义的MBR仅指引导程序而言。　　
硬盘的0柱面、0磁头、1扇区称为主引导扇区（也叫主引导记录MBR）。它由三个部分组成，主引导程序、硬盘分区表DPT（Disk Partition table）和硬盘有效标志（55AA）。在总共512字节的主引导扇区里主引导程序（boot loader）占446个字节，第二部分是Partition table区（分区表），即DPT，占64个字节，硬盘中分区有多少以及每一分区的大小都记在其中。第三部分是magic  number，占2个字节，固定为55AA。

我们来实现在VC++下面实现读取MBR。
C++内联汇编
在C++代码中插入__asm {}即可

1. ;**************************************************
2. .386p
3. .model flat, stdcall      ;平坦内存模式
4. option casemap :none   ; 大小写敏感
5. ;***************************************************
6. include \masm32\include\windows.inc
7. include \masm32\include\user32.inc
8. include \masm32\include\kernel32.inc
9. include \masm32\include\advapi32.inc
10.       
11. includelib \masm32\lib\user32.lib
12. includelib \masm32\lib\kernel32.lib
13. includelib \masm32\lib\advapi32.lib
15. ShowError proto :DWORD
16. ShowBuffer proto
18. .data                            ;数据段
19.         FileName db '\\.\PHYSICALDRIVE0',0  ;打开第一个物理硬盘
20.         align 4                                ;双字对齐
21.         readed        dd  0          ;实际读出的字节数
22.         Buffer    db  512 dup (0)  ;存放读出的数据的缓冲区
23.         hFile             dd  0          ;句柄存放处
24.        
25.         Caption                db 'NT中读写物理磁盘',0      ;Caption的字符串
26.         ErrCreate        db   '建文件错，该程序不能在Win9X下执行!',0   ;出错信息
27.         ErrRead                db '读盘错误！',0                           ;出错信息
28.        
29.         ShowText        db   4096*3 dup (0)               ;转换后用于显示的字符串
30.         Number        db '0123456789ABCDEF'           ;16进制数转换为ACSII码要用到的数据
32. .code                                                ;代码段
33. main:
34.         ;建立文件
35.         invoke CreateFile,offset FileName,\
36. GENERIC_READ,FILE_SHARE_READ OR FILE_SHARE_WRITE,\
37. NULL,OPEN_EXISTING,NULL,NULL
38.         mov  [hFile],eax
39.         cmp  eax,INVALID_HANDLE_VALUE
40.         jnz  read
41.         invoke ShowError,offset ErrCreate            ;显示错误信息
42. read:                                                   ;读数据
43.         invoke ReadFile,eax,offset Buffer,512,offset readed,NULL
44.         cmp  eax,0
45.         jnz  show
46.         invoke ShowError,offset ErrRead                    ;显示错误信息
47. show:                                                  
48.         invoke ShowBuffer                           ;显示读出的内容
49.         invoke CloseHandle ,[hFile]                        ;关闭文件句柄
50.         invoke ExitProcess,0                                ;退出
51. ShowError  proc ,MESSAGE:DWORD                               ;显示出错信息并退出
52.         invoke MessageBoxA,NULL,MESSAGE,offset Caption,MB_OK
53.         cmp  [hFile],0
54.         jz   ShowErrorEnd
55.         invoke CloseHandle ,[hFile]        ;关闭句柄
56. ShowErrorEnd:
57.         invoke ExitProcess,0                ;退出
58. ShowError  endp
60. ShowBuffer  proc                                            ;显示所读出的信息
61.                                                 ;把16进制数据转换成ASCII码的形式
62.         mov  esi,offset Buffer                ;数据
63.         mov  edi,offset ShowText         ;转换后的数据
64.         mov  ebx,offset Number
65.         mov  ecx,0
66.         xor  eax,eax
67. Again:
68.         cmp  [readed],0
69.         jz   ConversionEnd
70.         dec  [readed]
71.         mov  al,[esi]
72.         push eax
73.                  shr  eax,4                                 ;高4位
74.         mov  al,[ebx+eax]
75.         mov  byte ptr[edi],al
76.                  inc  edi
77.         pop  eax
78.         and  eax,0FH                            ;低4位
79.                  mov  al,[ebx+eax]
80.         mov  byte ptr[edi],al
81. inc  edi
82.                  mov  byte ptr[edi],' '                ;空格
83.         inc  edi
84.                  inc  esi
85.                  inc  ecx
86.         cmp  ecx,16
87.         jnz  Again
88.         xor  ecx,ecx
89.         mov  byte ptr[edi-1],13                ;是回车
90.         jmp  Again
91. ConversionEnd:
92. ;显示转换后的字符串
93.         invoke MessageBoxA,NULL,offset ShowText,offset Caption,MB_OK
94.         ret
95. ShowBuffer  endp
96.         end main

复制代码

作者：yincheng01 发表于2012-1-6 6:35:35 原文链接